!************************************
! Preset DFT amp- en fasespectrum.txt
!************************************

Declareer c; f; w; Ndft; Ndft2; r

Functienamen weergeven in Memo: nee

Naam Buffer F1 = In
Naam Buffer F2 = Re
Naam Buffer F3 = Im
Naam Buffer F4 = Amp
Naam Buffer F5 = Fase

!----------------------------------------------
! Maak zaagtand toon van Fs/256 Hz:

Wis buffers
  Wis buffer (F1...F32, S1, S2, S3)   In | Re | Im  | Amp | Fase

! Maak zaagtandgolf d.m.v. additieve synthese van sinusgolven
c = 2 * pi * Ts

FOR k = 1 TO 15
  f = k* Fs / 256
  w = f*c
  Bewerk signaal
    n0          0
    n1          Ndft - 1
    Bewerking   In[n] = In[n] + sin(w*n)/k
NEXT k

!----------------------------------------------
! DFT: bereken amplitudespectrum van zaagtandgolf:

Ndft  = 2^10
Ndft2 = Ndft/2
c     = 2*pi/Ndft
r     = 10 ^ (-20) ! klein getal toevoegen aan Re in atan(Im/Re) om deling door 0 te vermijden

FOR k = 0 TO Ndft2-1
  Re[k] = 0
  Im[k] = 0
  w = c*k
  Bewerk signaal
    n0          0
    n1          Ndft - 1
    Bewerking   Re[k] = Re[k] + cos(w*n)*In[n]
  Bewerk signaal
    n0          0
    n1          Ndft - 1
    Bewerking   Im[k] = Im[k] - sin(w*n)*In[n]
  
  Amp[k] = ((Re[k]^2 + Im[k]^2)^0,5) / Ndft
  Fase[k] = atan(Im[k]/(Re[k]+r))
!  Print Ndft2 - k
NEXT k

! Ampspectrum opschalen (om verhoudingen spectraallijnen
! zaagtand gemakkelijker te kunnen zien):
FOR k = 5 TO Ndft2-1
  Amp[k] = Amp[k] / Amp[4]
NEXT k
Amp[4] = 1

!----------------------------------------------
! Grafiek WaveWizard_2010

Grafische instellingen
  Afb       1
  Txfac     16
  Tyfac     300
  Stap      1
  Vanaf     0
  Aslang    960
  Asx       140
  Asy       400
  Modus     speld
  Kleur     rood
  Pendikte  2
  As        tijd

Achtergrondkleur
  Rood     255
  Groen    255
  Blauw    255

Raster met indices
  x0                  140
  y0                  100
  Breedte             960
  Hoogte              300
  HOR                 15
  VERT                10
  Pendikte            1
  Rood                159
  Groen               203
  Blauw               255
  start-index hor.    0
  eind-index hor.     16
  start-index vert.   100
  eind-index vert.    0
  aantal decimalen    0
  lettergrootte       10

Grafiek van F-buffer(s) Amp

!----------------------------------------------
! Grafiek WaveWizard_2012

Pen
  Kleur   rood
  Dikte   2
  Modus   continu    ! als Dikte = 1 dan ook 'stip' of 'streep' of 'streep-stip'

Grafiekpapier
  Linkerbovenhoek x; y (pix)   140; 600
  Breedte; Hoogte (pix)        1200; 600
  Domein x1; x2                0; 64
  Bereik y1; y2                0; 110
  Rooster x; y                 4; 5       ! geen roosterlijnen: 0;0

Grafiek van functie met 1 variabele
  f[x]     100* Amp[x]
  Domein   0;64
  Modus    speld        ! of 'sample' of 'speld'